source: svn/trunk/newcon3bcm2_21bu/dta/src/bootloader/bootloader3s.script

OUTPUT_ARCH(mips)
ENTRY(__start_s3)
/* Flash is located at 0xb8c00000 when boot_rom_enable=1 */
flash_start = 0x98c00000;

MEMORY
{
        FLASH(R)        : ORIGIN = 0x98c00000, LENGTH = 0x0007C000
        RAM(RW)         : ORIGIN = (0x80000000+0x01000000), LENGTH = (0x2000000-((0x80000000+0x01000000)-0x80000000))
    S3_RAM(RW): ORIGIN = (0x80000000), LENGTH = (0x16000)
}

SECTIONS
{
        .text : AT ( flash_start )
        {
                _ftext = .;
                *(.text)
                *(.text.*)
                *(.rodata)
                *(.rodata1)
                *(.rodata.str1.4)
                *(.rodata.cst4)
                *(.rodata.cst8)
                *(.fini)
                *(.reginfo)
                . = ALIGN(0x40);
        } > S3_RAM
        _etext = ( LOADADDR(.text) + SIZEOF(.text) );
        etext = ( LOADADDR(.text) + SIZEOF(.text) );
        _sdata = ADDR(.text) + SIZEOF(.text);
        .data : AT (_etext)
        {
                _fdata = .;
                *(data)
                SORT(CONSTRUCTORS)
                . = ALIGN(0x40);
        } > RAM

        
        _edata  =  .;
        _fbss = .;
        _stage3_start = LOADADDR(.text);
        _stage3_size = ( LOADADDR(.data) + SIZEOF(.data) - LOADADDR(.text));

        _ram_image_start = flash_start + 0x20000;
        _ram_image2_start = _ram_image_start + (29 * 0x10000);

        .sbss (NOLOAD) : 
        {
                *(.sbss)
                *(.scommon)
        }
        
        .bss (NOLOAD) :
        {
                _bss_start = .;
                *(.bss)
                *(COMMON)
                . = ALIGN(4);
        } > RAM
        
        . = ALIGN(4);
        _end = .;
        PROVIDE(_end = .);
        end = .;
        PROVIDE(end = .);
}